Aula nº10

Gráficos (continuação)

Como fazer com que o Maple faça uma circunferência? Há várias maneiras. Uma que é natural, dado o que se acabou de ver, é a seguinte:

> display(plot(sqrt(1-x^2),x=-1..1,scaling=constrained,xtickmarks=4,
labels=["",""]),plot(-sqrt(1-x^2),x=-1..1));

Matematicamente, é mais natural descrever a circunferências parametricamente, fazendo

> plot([cos(t),sin(t),t=0..2*Pi],scaling=constrained,xtickmarks=4,
labels=["",""]);

ou

> plot([(t^2-1)/(t^2+1),2*t/(t^2+1),t=-infinity..infinity],
scaling=constrained,xtickmarks=4,labels=["",""]);

Também podem ser empregues coordenadas polares

> plot([1,t,t=0..2*Pi],coords=polar,scaling=constrained,xtickmarks=4,
labels=["",""]);

Finalmente, há o recurso às funções definidas implicitamente

> implicitplot(x^2+y^2=1,x=-1..1,y=-1..1,
scaling=constrained,xtickmarks=4,labels=["",""]);

Uso de números aleatórios

Para criar números aleatórios faz-se

> rand();

Isto produz um número inteiro não negativo com não mais do que 12 algarismos. Assim, pode-se criar uma lista de pares de pontos aleatórios do quadrado que tem por vértices (1,1), (1,-1), (-1,1) e (-1,-1) fazendo

> lista:=[seq([2*rand()/10^12-1,2*rand()/10^12-1],k=1..1000)]:

A lista pode ser visualizada fazendo

> plot(lista,style=point,symbol=cross,scaling=constrained,color=green);

ou então

> pointplot(lista,symbol=cross,scaling=constrained,color=green);

Como ver quais destes pontos ficam na circunferência unitária? Pode-se fazer

> plot_lista:=plot(lista,style=point,symbol=cross,scaling=constrained,
color=green):
circunf:=plot([cos(t),sin(t),t=0..2*Pi],scaling=constrained,xtickmarks=4,
labels=["",""]):
display({circunf,plot_lista});

Para definir uma função «por bocados» faz-se, por exemplo

> f:=x->piecewise(x<-1,-1,x>1,1,x);

O seu gráfico é dado por

> plot(f(x),x=-3..3);