breed [sharks shark]
breed [minnows minnow]



globals [
    starvations
    death_sharks
    kills 
    mutations
    mutations1
    time]
    
patches-own [
  plankton]
    
turtles-own [
    cruise-speed
    burst-speed
    wiggle-angle
    turn-angle 
    field-of-view
    sight-range
    energy
    genome
    age]
minnows-own [ avoid-angle 
  escape-angle safety-range ]
 
sharks-own [shark-food-energy 
  shark_metabolism genome1]

to setup
  __clear-all-and-reset-ticks
    set mutations (list  0.1 0.1 5 0.5 0.1 2 2 2 )
    set mutations1 (list  0.1 0.1 5 2 2 )
    create-minnows minnow-population [
        setxy random-xcor random-ycor
        set shape "minnow"
        set wiggle-angle  5
        set cruise-speed 1
        set burst-speed 2
        set field-of-view 360
        set sight-range 5
        set safety-range 1
        set turn-angle 5
        set avoid-angle 15
        set escape-angle 15
        set energy birth-energy + random-float birth-energy
        set age random 200
        set genome (list cruise-speed burst-speed field-of-view 
          sight-range safety-range turn-angle avoid-angle escape-angle )
        if shade-of? turquoise color or shade-of? gray color 
        [set color red] 
        grow]      
    repeat shark-population [make-sharks random-xcor random-ycor]
    ask patches [ set plankton random 3 ]
    repeat 5 [diffuse plankton 1 ]
    ask patches [ set pcolor scale-color turquoise plankton 0 12 ]   
    set starvations 0
    set kills 0
    set time  0
end
        
to go
   set time time + 1
   
   ask patches [ 
       if plankton < 5 [
           if random-float 100 < (plankton-growth-rate)  [ 
              set plankton plankton  + 1  ] ]  ]
   diffuse plankton 1        
   ask patches [ set pcolor scale-color turquoise plankton 0 12]   
    ask minnows [ without-interruption [
        swim
        feed  
        set age age + 1
        grow ] ]
    ask minnows [ without-interruption [birth death ] ]

    ask sharks [ without-interruption [hunt birth_shark death
        set age age + 1 ]  ]
    do-plots
end


to make-sharks [x y]
        create-sharks 1 [
            set heading random 360
            setxy x y
            set color grey
            set size 4
            set shape "shark"
            set cruise-speed 1.5
            set burst-speed 3
            set wiggle-angle 5
            set turn-angle 10
            set field-of-view 120
            set sight-range 10
            set energy 100
            set shark-food-energy 7
            set age random 200
            set shark_metabolism 0.3
            set genome1 (list cruise-speed burst-speed field-of-view sight-range turn-angle ) ]
end

to swim
        set energy energy - metabolism
        let danger sharks in-cone sight-range field-of-view
        ifelse (any? danger) 
          [ avoid (min-one-of danger [distance myself ]) escape-angle
            fd burst-speed 
            set energy energy - burst-speed * drag-factor ]
          [ school ]
end 

to cruise
   rt random wiggle-angle 
   lt random wiggle-angle
   fd cruise-speed
   set energy energy - cruise-speed * drag-factor
end


to hunt 
    set energy energy - shark_metabolism
    let prey minnows in-cone sight-range field-of-view
    ifelse  (any? prey)
        [ let targets prey in-radius 2  
          ifelse any? targets
              [ ask one-of targets [die]
                set kills kills + 1 
                set energy energy + shark-food-energy ]                     
              [ approach min-one-of prey [distance myself] turn-angle 
                fd burst-speed
                set energy energy - burst-speed * drag-factor ] ] 
        [ cruise ]
end


to school
    let schoolmates minnows in-cone sight-range field-of-view with [(distance myself > 0.1) ]
    ifelse any? schoolmates      
        [let buddy min-one-of schoolmates [distance myself] 
         ifelse distance buddy  < safety-range
             [ avoid buddy avoid-angle ]         
             [ foreach sort schoolmates [
                  let adjusted-turn-angle turn-angle * exp( ((distance buddy) - (distance ?) ) )
                  approach ? adjusted-turn-angle
                  align ? adjusted-turn-angle ]]  
         cruise]
        [cruise]
end

;; shark or minnow procedure to turn in the direction of a target turtle by at most the specified turn angle
to approach [target max-angle]
   let angle subtract-headings towards target heading
              ifelse abs (angle) > max-angle 
                  [ ifelse angle > 0 [right max-angle ][left max-angle] ]
                  [ right angle ] 
end


to align [target max-angle]
   let angle subtract-headings [heading] of target heading
              ifelse abs (angle) > max-angle 
                  [ ifelse angle > 0 [right max-angle ][left max-angle] ]
                  [ right angle ] 
end


to avoid [target max-angle]
   let angle subtract-headings ((towards target) + 180) heading
              ifelse abs(angle) > max-angle
                  [ ifelse angle > 0 [right max-angle ][left max-angle] ]
                  [ right angle ] 
end


to feed
    if plankton >= 1
       [ set energy energy + minnow-food-energy
         set plankton plankton - 1]
end

to birth
    if (energy > 2 * birth-energy)   [
        set energy energy - birth-energy
        hatch 1 [ 
           set age 0
           set energy birth-energy 
           set heading random 360
           if mutation?  [mutate] ;; mutate the genome
           fd cruise-speed ] ]
end
to birth_shark
    if (energy > 150)   [
        set energy energy - 50
        hatch 1 [ 
           set age 0
           set energy 50
           set heading random 360
           if mutation?  [mutate_shark] ;; mutate the genome
           fd cruise-speed ] ]
end

to death
    if (energy < 0) [ 
        ifelse breed = minnows
            [set starvations starvations + 1 ]
            [set death_sharks death_sharks + 1]
        die ]
end


to grow
        ifelse age > 300 
           [set size 2 ]
           [set size 0.8 + age * 0.004 ]
       set color scale-color color (energy ) 0  (2 * birth-energy + 50)
end


to mutate
    let i 0
    let temp 0
    while [i < ( length genome ) ][
      ifelse (random 2 = 0) 
        [set temp item i genome] 
      [ifelse ((random 2) = 0 )
        [set temp item i genome + item i mutations ]
        [set temp item i genome - item i mutations ]]
      if (temp <= 0) [set temp item i mutations ]
      set genome replace-item i genome temp
      set i i + 1
    ]
    set cruise-speed item 0 genome 
    set burst-speed  item 1 genome
    if item 2 genome > 360 [set genome replace-item 2 genome 360]
    set field-of-view  item 2 genome
    set sight-range  item 3 genome
    if item 4 genome > sight-range [set genome replace-item 4 genome sight-range] 
    set safety-range  item 4 genome    
    set turn-angle  item 5 genome
    set avoid-angle  item 6 genome
    set escape-angle  item 7 genome
end 
to mutate_shark
    let i 0
    let temp 0
    while [i < ( length genome1 ) ][
      ifelse (random 2 = 0) 
        [set temp item i genome1] 
      [ifelse ((random 2) = 0 )
        [set temp item i genome1 + item i mutations1 ]
        [set temp item i genome1 - item i mutations1 ]]
      if (temp <= 0) [set temp item i mutations1]
      set genome1 replace-item i genome1 temp
      set i i + 1
    ]
    set cruise-speed item 0 genome1 
    set burst-speed  item 1 genome1
    if item 2 genome1 > 360 [set genome1 replace-item 2 genome1 360]
    set field-of-view  item 2 genome1
    set sight-range  item 3 genome1
    set turn-angle  item 4 genome1
end

to do-plots
    set-current-plot "Population"
    set-current-plot-pen "minnows"
    plot count minnows
    set-current-plot "Population-sharks"
    set-current-plot-pen "sharks"
    plot count sharks
end
@#$#@#$#@
GRAPHICS-WINDOW
363
10
865
533
20
20
12.0
1
10
1
1
1
0
1
1
1
-20
20
-20
20
0
0
1
ticks
30.0

BUTTON
5
10
73
43
NIL
setup
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SLIDER
3
46
148
79
minnow-population
minnow-population
100
300
160
10
1
NIL
HORIZONTAL

BUTTON
79
10
146
43
NIL
go
T
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

MONITOR
13
527
81
572
minnows
count minnows
3
1
11

SLIDER
4
157
149
190
plankton-growth-rate
plankton-growth-rate
1
2
1.7
0.1
1
NIL
HORIZONTAL

SLIDER
3
82
148
115
shark-population
shark-population
0
20
2
1
1
NIL
HORIZONTAL

PLOT
15
317
320
496
Population
time
population
0.0
10.0
0.0
10.0
true
true
"" ""
PENS
"minnows" 1.0 0 -16777216 true "" ""
"sharks" 1.0 0 -7500403 true "" ""

MONITOR
85
528
156
573
NIL
starvations
3
1
11

MONITOR
157
528
236
573
total kills
kills
3
1
11

BUTTON
874
238
1018
271
Remove Sharks
ask sharks [die]
NIL
1
T
OBSERVER
NIL
NIL
NIL
NIL
1

SWITCH
175
10
285
43
mutation?
mutation?
0
1
-1000

MONITOR
242
100
326
145
burst speed
mean [burst-speed] of minnows
3
1
11

MONITOR
158
153
238
198
field of view
mean [field-of-view] of minnows
3
1
11

MONITOR
241
153
327
198
sight range
mean [sight-range] of minnows
3
1
11

MONITOR
240
259
326
304
turn angle
mean [turn-angle] of minnows
3
1
11

MONITOR
157
207
234
252
avoid angle
mean [avoid-angle] of minnows
3
1
11

MONITOR
156
260
234
305
escape angle
mean [escape-angle] of minnows
3
1
11

MONITOR
239
205
326
250
safety range
mean [safety-range] of minnows
3
1
11

SLIDER
3
197
146
230
birth-energy
birth-energy
0
100
50
1
1
NIL
HORIZONTAL

SLIDER
6
120
149
153
minnow-food-energy
minnow-food-energy
0
10
9
0.1
1
NIL
HORIZONTAL

MONITOR
157
100
239
145
cruise speed
mean [cruise-speed] of minnows
3
1
11

MONITOR
239
527
320
572
death rate
(kills + starvations) / time
3
1
11

SLIDER
5
234
146
267
drag-factor
drag-factor
0
1
0.5
0.05
1
NIL
HORIZONTAL

SLIDER
5
271
146
304
metabolism
metabolism
0
0.2
0.01
0.01
1
NIL
HORIZONTAL

MONITOR
870
50
954
95
Mean Energy
mean [energy] of sharks
17
1
11

MONITOR
970
49
1043
94
Nº sharks
count sharks
17
1
11

MONITOR
871
107
953
152
Burst speed
mean [burst-speed] of sharks
17
1
11

MONITOR
969
107
1044
152
sight range
mean [sight-range] of sharks
17
1
11

MONITOR
873
163
953
208
field of view
mean [field-of-view] of sharks
17
1
11

TEXTBOX
938
20
1088
38
Sharks
11
0.0
1

PLOT
871
296
1119
446
Population-sharks
time
population
0.0
10.0
0.0
10.0
true
false
"" ""
PENS
"sharks" 1.0 0 -7500403 true "" ""

TEXTBOX
217
67
367
85
Minnows
11
0.0
1

MONITOR
969
161
1046
206
NIL
death_sharks
17
1
11

@#$#@#$#@


## WHAT IS IT?

This model is a predator prey model with sharks and minnows, which illustrates the principle of evolution. The minnows are programmed with certain behaviors, such as movement, feeding, reproduction, evading sharks and more complex behaviors that can lead to schooling under certain conditions. Sharks hunt minnows and feed on them. The parameters that determine the minnow behaviors evolve as minnows die and are born.

## HOW IT WORKS

The model Sharks_and_Minnows has more details about the shark and minnow population dynamics, including the parameters that determine how sharks and minnows reproduce, feed, and move, and how minnows evade sharks and school.  In this model the parameters that govern these behaviors are specified as a �genome� for each minnow, rather than being specified by sliders on the interface. The genome is specified as a list of parameter values. Initially each minnow has a randomly assigned genome and consequently the minnows do not exhibit particularly effective shark evading or schooling behavior. However, sharks hunt and eat minnows and the survivors reproduce. In addition, some minnows reproduce more rapidly, depending on how much energy they consume and food they eat. New minnows inherit the genome of their parent, but with some small mutation, determined by a particular mutation rate for each gene. As time passes the behavior of the minnows evolves to one that increases the chances of survival. The exact behavior that evolves can be different in different simulations. 

## HOW TO USE IT

Choose initial minnows and shark populations. Then choose the global parameters such as food-energy, plankton-growth-rate, birth-energy, drag-coefficient and metabolism and run the simulation. For some combinations the minnows will die out. Adjust them so that the population does not die out. Once you have relatively stable dynamics allow the simulation to run long enough for the evolutionary trend to become obvious.  This may take some time. Eventually one color will come to dominate � this is survival of the fittest. After a bit longer the behavior of this �species� will also evolve.

## THINGS TO TRY AND NOTICE

Try varying the number of sharks that you add. The behavior that evolves will be quite different with one than it will be with many. You can remove sharks by clicking the button. You can add sharks by clicking on the world-view.


Occasionally the minnows will adopted schooling behavior and move as a group to avoid sharks. On other occasions they will evolve to swim faster than the sharks, but will not exhibit a tendency to school. Sometimes minnows do not evolve to be particularly effective at avoiding sharks, but instead evolve behaviors that help them reproduce rapidly. The behaviors that evolve depend on some global parameters, such as metabolism, food-energy, and the drag coefficient. For example, with the drag coefficient low, the minnows end up moving rapidly (since the energy cost of movement is not high).  One thing to notices is that even when the global parameters are fixed, the minnows do not always evolve in the same direction.

If you run the simulation for a long time, the death rate will decrease, and the population of minnows will stabilize. 


## EXTENDING THE MODEL

In this model, minnows often eventually evolve to evade sharks almost entirely. In nature the predators often evolve along with the prey. Sharks have parameters or genes that govern minnow hunting behaviors, such as burst speed and sight range, but these genes don't evolve in this simulation. For sharks to evolve there needs to be some mechanism for them to die if they are unsuccessful at catching minnows. It should be relatively simple to give sharks a genome similar to that of the minnows, and have new sharks hatch with slightly mutated genes. Having sharks evolve could setup the possibility for an "arms race" behavior where minnows and sharks become faster and faster, or minnows might simply learn to school more closely, or learn to turn more quickly. 

## RELATED MODELS

This model is the second of two models on shark minnow population dynamics. The first one does not include evolution, but instead allows the user to choose the parameters and behaviors of the sharks and minnows.

## COPYRIGHT NOTICE

   Copyright 2006 David McAvity

This model was created at the Evergreen State College, in Olympia Washington  
as part of a series of applets to illustrate principles in physics and biology. 

Funding was provided by the Plato Royalty Grant.
   
The model may be freely used, modified and redistributed provided this copyright is included and it not used for profit.

Contact David McAvity at mcavityd@evergreen.edu if you have questions about its use.
@#$#@#$#@
default
true
0
Polygon -7500403 true true 150 5 40 250 150 205 260 250

airplane
true
0
Polygon -7500403 true true 150 0 135 15 120 60 120 105 15 165 15 195 120 180 135 240 105 270 120 285 150 270 180 285 210 270 165 240 180 180 285 195 285 165 180 105 180 60 165 15

arrow
true
0
Polygon -7500403 true true 150 0 0 150 105 150 105 293 195 293 195 150 300 150

box
false
0
Polygon -7500403 true true 150 285 285 225 285 75 150 135
Polygon -7500403 true true 150 135 15 75 150 15 285 75
Polygon -7500403 true true 15 75 15 225 150 285 150 135
Line -16777216 false 150 285 150 135
Line -16777216 false 150 135 15 75
Line -16777216 false 150 135 285 75

bug
true
0
Circle -7500403 true true 96 182 108
Circle -7500403 true true 110 127 80
Circle -7500403 true true 110 75 80
Line -7500403 true 150 100 80 30
Line -7500403 true 150 100 220 30

butterfly
true
0
Polygon -7500403 true true 150 165 209 199 225 225 225 255 195 270 165 255 150 240
Polygon -7500403 true true 150 165 89 198 75 225 75 255 105 270 135 255 150 240
Polygon -7500403 true true 139 148 100 105 55 90 25 90 10 105 10 135 25 180 40 195 85 194 139 163
Polygon -7500403 true true 162 150 200 105 245 90 275 90 290 105 290 135 275 180 260 195 215 195 162 165
Polygon -16777216 true false 150 255 135 225 120 150 135 120 150 105 165 120 180 150 165 225
Circle -16777216 true false 135 90 30
Line -16777216 false 150 105 195 60
Line -16777216 false 150 105 105 60

car
false
0
Polygon -7500403 true true 300 180 279 164 261 144 240 135 226 132 213 106 203 84 185 63 159 50 135 50 75 60 0 150 0 165 0 225 300 225 300 180
Circle -16777216 true false 180 180 90
Circle -16777216 true false 30 180 90
Polygon -16777216 true false 162 80 132 78 134 135 209 135 194 105 189 96 180 89
Circle -7500403 true true 47 195 58
Circle -7500403 true true 195 195 58

circle
false
0
Circle -7500403 true true 0 0 300

circle 2
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240

cow
false
0
Polygon -7500403 true true 200 193 197 249 179 249 177 196 166 187 140 189 93 191 78 179 72 211 49 209 48 181 37 149 25 120 25 89 45 72 103 84 179 75 198 76 252 64 272 81 293 103 285 121 255 121 242 118 224 167
Polygon -7500403 true true 73 210 86 251 62 249 48 208
Polygon -7500403 true true 25 114 16 195 9 204 23 213 25 200 39 123

cylinder
false
0
Circle -7500403 true true 0 0 300

dot
false
0
Circle -7500403 true true 90 90 120

face happy
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 255 90 239 62 213 47 191 67 179 90 203 109 218 150 225 192 218 210 203 227 181 251 194 236 217 212 240

face neutral
false
0
Circle -7500403 true true 8 7 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Rectangle -16777216 true false 60 195 240 225

face sad
false
0
Circle -7500403 true true 8 8 285
Circle -16777216 true false 60 75 60
Circle -16777216 true false 180 75 60
Polygon -16777216 true false 150 168 90 184 62 210 47 232 67 244 90 220 109 205 150 198 192 205 210 220 227 242 251 229 236 206 212 183

fish
false
0
Polygon -1 true false 44 131 21 87 15 86 0 120 15 150 0 180 13 214 20 212 45 166
Polygon -1 true false 135 195 119 235 95 218 76 210 46 204 60 165
Polygon -1 true false 75 45 83 77 71 103 86 114 166 78 135 60
Polygon -7500403 true true 30 136 151 77 226 81 280 119 292 146 292 160 287 170 270 195 195 210 151 212 30 166
Circle -16777216 true false 215 106 30

flag
false
0
Rectangle -7500403 true true 60 15 75 300
Polygon -7500403 true true 90 150 270 90 90 30
Line -7500403 true 75 135 90 135
Line -7500403 true 75 45 90 45

flower
false
0
Polygon -10899396 true false 135 120 165 165 180 210 180 240 150 300 165 300 195 240 195 195 165 135
Circle -7500403 true true 85 132 38
Circle -7500403 true true 130 147 38
Circle -7500403 true true 192 85 38
Circle -7500403 true true 85 40 38
Circle -7500403 true true 177 40 38
Circle -7500403 true true 177 132 38
Circle -7500403 true true 70 85 38
Circle -7500403 true true 130 25 38
Circle -7500403 true true 96 51 108
Circle -16777216 true false 113 68 74
Polygon -10899396 true false 189 233 219 188 249 173 279 188 234 218
Polygon -10899396 true false 180 255 150 210 105 210 75 240 135 240

house
false
0
Rectangle -7500403 true true 45 120 255 285
Rectangle -16777216 true false 120 210 180 285
Polygon -7500403 true true 15 120 150 15 285 120
Line -16777216 false 30 120 270 120

leaf
false
0
Polygon -7500403 true true 150 210 135 195 120 210 60 210 30 195 60 180 60 165 15 135 30 120 15 105 40 104 45 90 60 90 90 105 105 120 120 120 105 60 120 60 135 30 150 15 165 30 180 60 195 60 180 120 195 120 210 105 240 90 255 90 263 104 285 105 270 120 285 135 240 165 240 180 270 195 240 210 180 210 165 195
Polygon -7500403 true true 135 195 135 240 120 255 105 255 105 285 135 285 165 240 165 195

line
true
0
Line -7500403 true 150 0 150 300

line half
true
0
Line -7500403 true 150 0 150 150

link
true
0
Line -7500403 true 150 0 150 300

link direction
true
0
Line -7500403 true 150 150 30 225
Line -7500403 true 150 150 270 225

minnow
true
0
Polygon -7500403 true true 150 15 136 32 118 80 105 90 90 120 105 120 115 145 125 208 131 259 120 285 135 285 165 285 150 261 167 208 177 141 180 120 195 120 195 105 178 80 162 32

pentagon
false
0
Polygon -7500403 true true 150 15 15 120 60 285 240 285 285 120

person
false
0
Circle -7500403 true true 110 5 80
Polygon -7500403 true true 105 90 120 195 90 285 105 300 135 300 150 225 165 300 195 300 210 285 180 195 195 90
Rectangle -7500403 true true 127 79 172 94
Polygon -7500403 true true 195 90 240 150 225 180 165 105
Polygon -7500403 true true 105 90 60 150 75 180 135 105

plant
false
0
Rectangle -7500403 true true 135 90 165 300
Polygon -7500403 true true 135 255 90 210 45 195 75 255 135 285
Polygon -7500403 true true 165 255 210 210 255 195 225 255 165 285
Polygon -7500403 true true 135 180 90 135 45 120 75 180 135 210
Polygon -7500403 true true 165 180 165 210 225 180 255 120 210 135
Polygon -7500403 true true 135 105 90 60 45 45 75 105 135 135
Polygon -7500403 true true 165 105 165 135 225 105 255 45 210 60
Polygon -7500403 true true 135 90 120 45 150 15 180 45 165 90

shark
true
0
Polygon -7500403 true true 150 15 164 32 182 80 204 98 210 113 189 117 185 145 175 208 169 259 200 277 168 276 135 298 150 261 133 208 123 141 123 116 99 123 104 106 122 80 138 32

square
false
0
Rectangle -7500403 true true 30 30 270 270

square 2
false
0
Rectangle -7500403 true true 30 30 270 270
Rectangle -16777216 true false 60 60 240 240

star
false
0
Polygon -7500403 true true 151 1 185 108 298 108 207 175 242 282 151 216 59 282 94 175 3 108 116 108

target
false
0
Circle -7500403 true true 0 0 300
Circle -16777216 true false 30 30 240
Circle -7500403 true true 60 60 180
Circle -16777216 true false 90 90 120
Circle -7500403 true true 120 120 60

tree
false
0
Circle -7500403 true true 118 3 94
Rectangle -6459832 true false 120 195 180 300
Circle -7500403 true true 65 21 108
Circle -7500403 true true 116 41 127
Circle -7500403 true true 45 90 120
Circle -7500403 true true 104 74 152

triangle
false
0
Polygon -7500403 true true 150 30 15 255 285 255

triangle 2
false
0
Polygon -7500403 true true 150 30 15 255 285 255
Polygon -16777216 true false 151 99 225 223 75 224

truck
false
0
Rectangle -7500403 true true 4 45 195 187
Polygon -7500403 true true 296 193 296 150 259 134 244 104 208 104 207 194
Rectangle -1 true false 195 60 195 105
Polygon -16777216 true false 238 112 252 141 219 141 218 112
Circle -16777216 true false 234 174 42
Rectangle -7500403 true true 181 185 214 194
Circle -16777216 true false 144 174 42
Circle -16777216 true false 24 174 42
Circle -7500403 false true 24 174 42
Circle -7500403 false true 144 174 42
Circle -7500403 false true 234 174 42

turtle
true
0
Polygon -10899396 true false 215 204 240 233 246 254 228 266 215 252 193 210
Polygon -10899396 true false 195 90 225 75 245 75 260 89 269 108 261 124 240 105 225 105 210 105
Polygon -10899396 true false 105 90 75 75 55 75 40 89 31 108 39 124 60 105 75 105 90 105
Polygon -10899396 true false 132 85 134 64 107 51 108 17 150 2 192 18 192 52 169 65 172 87
Polygon -10899396 true false 85 204 60 233 54 254 72 266 85 252 107 210
Polygon -7500403 true true 119 75 179 75 209 101 224 135 220 225 175 261 128 261 81 224 74 135 88 99

wheel
false
0
Circle -7500403 true true 3 3 294
Circle -16777216 true false 30 30 240
Line -7500403 true 150 285 150 15
Line -7500403 true 15 150 285 150
Circle -7500403 true true 120 120 60
Line -7500403 true 216 40 79 269
Line -7500403 true 40 84 269 221
Line -7500403 true 40 216 269 79
Line -7500403 true 84 40 221 269

x
false
0
Polygon -7500403 true true 270 75 225 30 30 225 75 270
Polygon -7500403 true true 30 75 75 30 270 225 225 270

@#$#@#$#@
NetLogo 5.0.5
@#$#@#$#@
@#$#@#$#@
1.0 
    org.nlogo.sdm.gui.AggregateDrawing 6 
        org.nlogo.sdm.gui.StockFigure "attributes" "attributes" 1 "FillColor" "Color" 225 225 182 127 75 60 40 
            org.nlogo.sdm.gui.WrappedStock "" "" 0   
        org.nlogo.sdm.gui.RateConnection 3 180 127 223 185 266 243 NULL NULL 0 0 0 
            org.jhotdraw.standard.ChopBoxConnector REF 1  
            org.jhotdraw.figures.ChopEllipseConnector 
                org.nlogo.sdm.gui.ReservoirFigure "attributes" "attributes" 1 "FillColor" "Color" 192 192 192 259 239 30 30   
            org.nlogo.sdm.gui.WrappedRate "" "" REF 2 
                org.nlogo.sdm.gui.WrappedReservoir  0   REF 6 
        org.nlogo.sdm.gui.BindingConnection 2 180 127 223 185 NULL NULL 0 0 0 
            org.jhotdraw.standard.ChopBoxConnector REF 1  
            org.nlogo.sdm.gui.ChopRateConnector REF 3   
        org.nlogo.sdm.gui.ConverterFigure "attributes" "attributes" 1 "FillColor" "Color" 130 188 183 134 87 50 50 
            org.nlogo.sdm.gui.WrappedConverter "" ""   
        org.nlogo.sdm.gui.StockFigure "attributes" "attributes" 1 "FillColor" "Color" 225 225 182 221 231 60 40 
            org.nlogo.sdm.gui.WrappedStock "" "" 0
@#$#@#$#@
<experiments>
  <experiment name="experiment" repetitions="1" runMetricsEveryStep="true">
    <setup>setup</setup>
    <go>go</go>
    <metric>count turtles</metric>
    <enumeratedValueSet variable="minnow-food-energy">
      <value value="2.5"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="shark-population">
      <value value="2"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="minnow-population">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="birth-energy">
      <value value="50"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="mutation?">
      <value value="true"/>
    </enumeratedValueSet>
    <enumeratedValueSet variable="plankton-growth-rate">
      <value value="1"/>
    </enumeratedValueSet>
  </experiment>
</experiments>
@#$#@#$#@
@#$#@#$#@
default
0.0
-0.2 0 0.0 1.0
0.0 1 1.0 0.0
0.2 0 0.0 1.0
link direction
true
0
Line -7500403 true 150 150 90 180
Line -7500403 true 150 150 210 180

@#$#@#$#@
0
@#$#@#$#@